Question

Faça um programa que leia uma matriz de ordem 3x3 de inteiros e armazene valores nela.
Faça uma segunda matriz de ordem 3x3 de inteiros e armazene valores nela.
Faça uma terceira matriz de ordem 3x3 de armazene nela a soma dos valores das duas matrizes anteriores.
No final o programa deve imprimir as 3 matrizes.

Estou fazendo informática mas não consegui entender como faço isso, se alguém puder me ajudar por favor agradeço

Answer 1

\texttt{Ol\'a! :D}\\\rule{7cm}{0.01mm}

algoritmo "Soma Matricial"

var

  i, j, auxiliar1, auxiliar2: inteiro

  matriz_A: vetor [0..2, 0..2] de inteiro

  matriz_B: vetor [0..2, 0..2] de inteiro

  matrizSoma: vetor [0..2, 0..2] de inteiro

inicio

  aleatorio 1, 1

  escreval("------ Entre com valores para a primeira matriz: ------")

  para i de 0 ate 2 passo 1 faca

     para j de 0 ate 2 passo 1 faca

        auxiliar1 <- i + 1

        auxiliar2 <- j + 1

        escreva("a",auxiliar1,auxiliar2," >>> ")

        leia(matriz_A[i,j])

     fimpara

  fimpara

  //limpatela

  escreval("------ Entre com valores para a segunda matriz: ------")

  para i de 0 ate 2 passo 1 faca

     para j de 0 ate 2 passo 1 faca

        auxiliar1 <- i + 1

        auxiliar2 <- j + 1

        escreva("b",auxiliar1,auxiliar2," >>> ")

        leia(matriz_B[i,j])

     fimpara

  fimpara

  //limpatela

   

  aleatorio off

   

  escreval("---------------------------------------------------")

  escreval("Exibindo a primeira matriz: (A) ")

  para i de 0 ate 2 passo 1 faca

     para j de 0 ate 2 passo 1 faca

        escreva(matriz_A[i,j])

     fimpara

     escreval("")

  fimpara

  escreval("---------------------------------------------------")

  escreval("Exibindo a segunda matriz: (B) ")

  para i de 0 ate 2 passo 1 faca

     para j de 0 ate 2 passo 1 faca

        escreva(matriz_B[i,j])

     fimpara

     escreval("")

  fimpara

  escreval("---------------------------------------------------")

  escreval("Exibindo a soma das matrizes acima: (A + B) ")

  para i de 0 ate 2 passo 1 faca

     para j de 0 ate 2 passo 1 faca

        matrizSoma[i,j] <- matriz_A[i,j] + matriz_B[i,j]

        escreva(matrizSoma[i,j])

     fimpara

     escreval("")

  fimpara

  escreva("---------------------------------------------------")

fimalgoritmo

Observação: Utilizei a função aleatório apenas para não ser preciso digitar nada, você pode configurar os intervalos dos valores para qualquer outro.

Ex.: aleatorio 0, 25

Ou seja os valores irão de 0 a 25. Você pode ainda comentar a linha onde tem a função aleatorio ou deletar se preferir fazer o processo manual.

Outra observação no ponto onde tem a função limpatela, fica a critério retirar o comentário para deixar mais clean a visualização no console.