Question

faça um algoritmo no visual g que leia 10 nomes e notas, calcule a maior nota e a menor nota ,a media das notas e mostre o nome do aluno que tirou a maior nota e mostre nome do aluno que tirou a menor nota e a media da turma.

Answer 1

Resposta:

Algoritmo "notas"

Var

  notas, notaMaior, notaMenor, somaNotas, media: real

  nomes, alunoMaiorNota, alunoMenorNota: caracter

  i: inteiro

Inicio

  i := 1

  notas := 0

  escreval("Digite o nome do aluno: ")

  leia(nomes)

  escreval("Digite a nota do aluno: ")

  leia(notas)

  alunoMaiorNota := nomes

  alunoMenorNota := nomes

  notaMaior := notas

  notaMenor := notas

  somaNotas := somaNotas + notas

  enquanto (i <= 9) faca

     escreval("Digite o nome do aluno: ")

     leia(nomes)

     escreval("Digite a nota do aluno: ")

     leia(notas)

     somaNotas := somaNotas + notas

     se (notas > notaMaior) entao

        notaMaior := notas

        alunoMaiorNota := nomes

     senao

        se (notas < notaMenor) entao

           notaMenor := notas

           alunoMenorNota := nomes

        fimse

     fimse

     i := i + 1

  fimenquanto

  media := somaNotas/10

  escreval("O aluno(a) ", alunoMaiorNota, " tirou ", notaMaior, " pontos que foi a maior nota.")

  escreval("O aluno(a) ", alunoMenorNota, " tirou ", notaMenor, " pontos que foi a menor nota.")

  escreval("A media das notas é igual a ", media)

Fimalgoritmo

Explicação:

O algoritmo solicita ao usuário o nome e a nota do aluno.

Esses dois primeiros valores são armazenados como a maior e menor, e também como o nome do aluno com a nota maior e a menor.

Como já foi solicitado ao usuário uma nota é criado um laço de repetição que irá rodar apenas 9 vez.

Dentro do loop é usado uma variável para armazenar o total das notas. É usado uma estrutura condicional para checar se a nota que o usuário digitou é a maior ou a menor até o momento.

Depois do fim do loop e calculado a media das notas.

E por fim é mostrado a media, o aluno com a maior e a menor nota.