Question

Desenvolva um algoritmo que receba 3 números ascendentes( do menor para o maior) e um quarto número qualquer, verifique esse quarto número com os outros anteriores e o coloque na devida posição.( ascendente) (VISUAL G)

Answer 1

Eu faria assim

 var 
numeros : vetor[1..4] de inteiro
intruso : inteiro 
i , j : inteiro 
menor : inteiro
inicio   
 escreval("Informe os 3 valores iniciais")   
 menor <- -99999   
 numeros[4] <- 99999 // truque para garantir que haverá um número maior
para i de 1 ate 3 faca
       escreval("Informe o valor ",i)
       leia(numeros[i])
       se (menor > numeros[i]) entao
           escreval( "Trapaça ! Os valores tem que estar em ordem ascendente")
           escreval("Assim não vai funcionar!")
       fimse
       menor <- numeros[i]
   fimpara
   escreval("Eis o conjunto de números original")
   para i de 1 ate 3     faca
       escreval( numeros[i])
   fimpara
   escreval()   // agora começa a brincadeira sérias
   escreval("por gentileza, informe o número a ser inserido")
   leia(intruso)
   escreval("O número a inserir é ",intruso)
   escreval()
   para i de 1 ate 4 faca
         se (numeros[i] > intruso) entao   // encontrou um maior
              para j de 4 ate i+1 passo -1  faca     // desloca para a direita
                  numeros[j] <- numeros[j-1]    // o elem i vai para i+1
              fimpara
              numeros[i] <- intruso      // tacamos o intruso no vetor
              interrompa
         fimse
   fimpara

   escreval("o conjunto de números ficou assim")
   para i de 1 ate 4 faca
       se (numeros[i] = intruso) entao
           escreva("*")
       fimse
       escreval( numeros[i])
   fimpara
     
 
fimalgoritmo